Резюме Zsh-Terminal (OS X Lion)

OS X Lion имеет функцию "Возобновить", т.е. при повторном открытии приложения оно восстанавливает все окна и их содержимое. Это работает и для Терминала. Но если вы используете Zsh вместо Bash, он не восстанавливает открытый каталог. Как я могу это исправить?

Источник

2 ответа

Решение

ОБНОВЛЕНИЕ: Это не совсем правильно, по причинам, указанным в комментариях. Используйте ответ ниже. Спасибо @ChrisPage за прохождение лишней мили:)

Ответ может быть найден путем обратного инжиниринга, как это делает bash. /etc/bashrc, Я перепробовал множество подходов со всей сети, но путь Apple, кажется, работает лучше всего (см. Рисунок).

В вашем .zshrc добавить следующее

# Set Apple Terminal.app resume directory
if [[ $TERM_PROGRAM == "Apple_Terminal" ]] && [[ -z "$INSIDE_EMACS" ]] {
  function chpwd {
    local SEARCH=' '
    local REPLACE='%20'
    local PWD_URL="file://$HOSTNAME${PWD//$SEARCH/$REPLACE}"
    printf '\e]7;%s\a' "$PWD_URL"
  }

  chpwd
}

Счастливого возобновления.

Для пояснения этот ответ относится к загадочному сообщению в настройках Terminal X. Lion в OS X:

** Программы уведомляют Терминал о текущем рабочем каталоге, используя escape-последовательности. Вам может потребоваться настроить вашу оболочку или другие программы, чтобы включить это поведение.*

Этот ответ работает, когда вы используете zsh в качестве оболочки. Резюме терминала для bash уже реализовано Apple.

Источник

Вот моя адаптация /etc/bashrc для zsh. Я включил процентное кодирование всех символов URL, которые в нем нуждаются, что важно, если вы хотите, чтобы это работало со всеми допустимыми именами файлов и каталогов.

Это регистрирует precmd хук, который позволяет регистрировать более одной функции в других скриптах и ​​файлах конфигурации.

ОБНОВЛЕНО март 2019 года: набор LC_ALL опустошить, чтобы он не перекрывал LC_CTYPE, использование precmd обновлять рабочий каталог при каждом запросе вместо использования chpwd обновлять его каждый раз, когда он изменяется - командные конвейеры могут временно изменить его, и терминал не должен отображать их. Кроме того, может быть полезно, чтобы каждая подсказка обновляла состояние терминала, если оно было изменено во время предыдущей команды. использование printf -v явно писать в переменную вместо использования синтаксиса subshell.

# Tell the terminal about the working directory whenever it changes.

if [[ "$TERM_PROGRAM" == "Apple_Terminal" ]] && [[ -z "$INSIDE_EMACS" ]]; then

    update_terminal_cwd() {
        # Identify the directory using a "file:" scheme URL, including
        # the host name to disambiguate local vs. remote paths.

        # Percent-encode the pathname.
        local url_path=''
        {
            # Use LC_CTYPE=C to process text byte-by-byte. Ensure that
            # LC_ALL isn't set, so it doesn't interfere.
            local i ch hexch LC_CTYPE=C LC_ALL=
            for ((i = 1; i <= ${#PWD}; ++i)); do
                ch="$PWD[i]"
                if [[ "$ch" =~ [/._~A-Za-z0-9-] ]]; then
                    url_path+="$ch"
                else
                    printf -v hexch "%02X" "'$ch"
                    url_path+="%$hexch"
                fi
            done
        }

        printf '\e]7;%s\a' "file://$HOST$url_path"
    }

    # Register the function so it is called at each prompt.
    autoload add-zsh-hook
    add-zsh-hook precmd update_terminal_cwd
fi
Источник
Другие вопросы по тегам