Есть ли в Spotify твики с сочетанием клавиш для "звездных" треков?

Я - премиальный подписчик Spotify и одержимый продуктивный гик.

Одна вещь, которая действительно раздражает меня, - то, что нет никакого сочетания клавиш, чтобы "пометить" дорожку (то есть добавить дорожку в избранное). Мне нравится оставлять радио Spotify включенным, пока я работаю, и время от времени мне приходится переходить между треками и щелкать правой кнопкой мыши по треку, а затем выбирать "Звезду" всякий раз, когда я слышу песню, которая мне действительно нравится.

Есть ли в Spotify твики / плагины, которые позволят мне "отмечать" треки с помощью сочетания клавиш?

Источник

7 ответов

Конечно, используйте AutoHotkey!

Установив его, поместите его в файл AutoHotkey.ahk:

#*::
WinWait, Spotify, 
IfWinNotActive, Spotify, , WinActivate, Spotify, 
WinWaitActive, Spotify, 
MouseClick, left,  79,  90
Sleep, 100
MouseClick, left,  256,  152
Sleep, 100
return

Это добавляет горячую клавишу Win+Asterisk, которая помечает дорожку, которая играет.

Вы также можете быть заинтересованы в других сочетаниях клавиш Spotify для AutoHotkey.

Источник

Я попробовал другой ярлык Autohotkey, и он не работал для меня (просто переключился на spotify и щелкнул в двух мертвых точках). Я разработал следующее, которое работает, если вы выбрали "Large Now Playing Artwork":

CoordMode, Mouse, Relative
;star currently playing
+^l::
SpotifyWinHeight = 1050 ;set to 1080 - 30 for small taskbar size, just in case WinGetPos doesn't work for some reason
WinGetActiveTitle, CurWindow
WinActivate Spotify
WinWaitActive Spotify
WinGetPos,  ,  ,  , SpotifyWinHeight, Spotify
;          X  Y  W  H, we don't care about anything but height
RightClickTarget := SpotifyWinHeight - 250
ContextMenuTarget := RightClickTarget + 110
MouseMove, 100, %RightClickTarget%
Click Right
Sleep, 50
MouseMove, 180, %ContextMenuTarget%
Sleep, 50
Click
WinActivate %CurWindow%
return

Это делает следующее:

  • Сохраняет текущее активное окно
  • Активирует Spotify
  • Вычисляет смещения при нажатии на обложку альбома относительно окна спойтирования.
  • Звезды, которые в настоящее время играют (с помощью правой кнопки мыши, левой кнопкой мыши нажмите Звезду)
  • Восстанавливает все окна, которые были активны до всего этого

Он не идеален (вероятно, не будет счастлив, если по какой-то причине у вас есть спрайты, в основном свисающие с экрана справа), но в большинстве случаев он выполняет свою работу.

Источник

Помечено больше не вещь.

Зайдите сюда для получения обновленных вопросов и ответов.

Старый ответ ниже здесь...

Вот еще одно решение AutoHotkey. Есть либеральные комментарии. Кроме того, документация и форумы AutoHotkey - отличные места для изучения при желании.

Нажатие Control+Shift+* запустит активную песню.
Ключевой особенностью этого скрипта является то, что он проверяет, не была ли песня уже помечена, и оставляет ее в покое, если это так.

^+*::
spotify = ahk_class SpotifyMainWindow
IfWinExist, %spotify%
{
;Store active window and mouse position.
WinGetActiveTitle, activeWindow
MouseGetPos x, y, winID

;Activate Spotify.
WinActivate %spotify%
WinWaitActive %spotify%

;Right click near the song title in the "Now Playing" box.
WinGetPos,  ,  ,  , spotifyHeight, %spotify%
MouseClick, Right, 100, spotifyHeight - 70, 1, 0

;Get the contents of the context menu.
WinWait, ahk_class #32768
SendMessage, 0x1E1      ; MN_GETHMENU
allContextMenuInfo := ErrorLevel

;The "Star" command is the 5th menu item.
;If the song is Unstarred the text is Star, and vice versa. But sometimes some wierd characters are included.
;The only reliable way I found is to check if the first letter is S.
menuText_StarUnstar := GetContextMenuItemText(allContextMenuInfo, 5)
StringGetPos, positionOfS, menuText_StarUnstar, S

;If S is the first letter, star the song.
notStarred := (%positionOfS% = 0)
If notStarred {
    ;Arrow down to the Star menu item and press enter.
    Send {Down}{Down}{Down}{Down}{Down}{Enter}
} Else {
    ;Just close the context menu.
    Send {Escape}
}

;Restore original window and mouse position.
WinActivate ahk_id %winID%
MouseMove %x%, %y%
}

Return

;Conext menu helper function.
GetContextMenuItemText(hMenu, nPos)
{
length := DllCall("GetMenuString"
        , "UInt", hMenu
        , "UInt", nPos
        , "UInt", 0 ; NULL
        , "Int", 0  ; Get length
        , "UInt", 0x0400)   ; MF_BYPOSITION
    VarSetCapacity(lpString, length + 1)
    length := DllCall("GetMenuString"
        , "UInt", hMenu
        , "UInt", nPos
        , "Str", lpString
        , "Int", length + 1
        , "UInt", 0x0400)
return lpString
}
Источник

Вы также можете попробовать мое приложение Spotify, Twinkle, которое является независимым от платформы и графического интерфейса решением для запуска песен Spotify одним щелчком мыши.

Источник

У Spotify больше нет "звездочки", и я больше не могу получить содержимое контекстного меню, поэтому этот метод смотрит на цвет пикселя в контекстном меню и использует клавиши со стрелками для выбора. Работает, если развернуто, свернуто и обложка альбома большая или маленькая.

^+*::
{
    spotify = ahk_class SpotifyMainWindow
    IfWinExist, %spotify% 
    {
        ;Store active window and mouse position.
        WinGet, MMX, MinMax, %spotify%
        WinGetActiveTitle, activeWindow
        MouseGetPos x, y, winID

        ;Activate Spotify.
        WinActivate %spotify%
        WinWaitActive %spotify%

        ;Get maximised status
        WinGet, isMaximised, MinMax

        ;Clear any context menus
        Send {Escape down}{Escape up}

        ;Right click near the song title in the "Now Playing" box.
        WinGetPos,  ,  ,  , spotifyHeight, %spotify%
        MouseClick, Right, 44, spotifyHeight - (isMaximised = 1 ? 75 : 66), 1, 0
        sleep 200
        MouseMove 10,0, ,R
        sleep 200

        ; Determine if the song is already added to your library or not
        ; Look at left edge of the 'S' in Save to Your Library
        ; or the 'R' in Remove from Your Library
        ; 0x282828 is the background color of the menu
        ; if the background color is not present then the song is not in your library
        PixelGetColor, pixelColor, 91, spotifyHeight - (isMaximised = 1 ? 129 : 119)
        if (pixelColor = 0x282828) {
            ;Move up to 'Save to Your Library' and hit enter
            loop, 1 {
                Send {Up down}
                sleep 50
                Send {Up up}
                sleep 50
            }
            Send {Enter down}
            sleep 50
            Send {Enter up}
            sleep 50
        } else {
            ; Already added, so close context menu
            Send {Escape down}
            sleep 50
            Send {Escape up}
            Sleep 50
        }

        ;Restore original window and mouse position.
        IfEqual MMX, -1, WinMinimize, %spotify%
        WinActivate ahk_id %winID%
        MouseMove %x%, %y%

    }
    Return
}
Источник

Решения, которые зависят от наличия команды "Звезда", больше не работают... больше нет команды "Звезда", но "Помечено" - это папка, в которую можно добавлять элементы. Этот скрипт делает это.

; Spotify "Star Song"
^+*::
spotify = ahk_class SpotifyMainWindow
IfWinExist, %spotify%
{
;Store active window and mouse position.
WinGetActiveTitle, activeWindow
MouseGetPos x, y, winID

;Activate Spotify.
WinActivate %spotify%
WinWaitActive %spotify%

;Right click near the song title in the "Now Playing" box.
WinGetPos,  ,  ,  , spotifyHeight, %spotify%
MouseClick, Right, 100, spotifyHeight - 70, 1, 0

;Open Add To... sub-menu
Send {A}

;The "Starred" command is the 2nd menu item. If the song is Starred it will be disabled.
Send {Down}{Enter}

;Restore original window and mouse position.
WinActivate ahk_id %winID%
MouseMove %x%, %y%
}

Return
Источник

У меня нет представителя, чтобы добавить это в комментарии к ответу GollyJer, но я заметил, что при попытке использовать этот скрипт возникла проблема с нажатиями клавиш {вниз}, которые каким-то образом заставляли бы перемещать выделенную песню в списке воспроизведения вниз вместо того, чтобы двигаться вниз по меню. Я изменил его, чтобы щелкнуть мышью по пункту меню "Звезда" вместо использования клавиш, похоже, он работает довольно хорошо. Я также отредактировал его, чтобы минимизировать Spotify, прежде чем он вернется к тому окну, которое вы использовали, если оно было свернуто с самого начала.

^+*::
spotify = ahk_class SpotifyMainWindow
IfWinExist, %spotify%
{
WinGet, MMX, MinMax, %spotify%
;Store active window and mouse position.
WinGetActiveTitle, activeWindow
MouseGetPos x, y, winID

;Activate Spotify.
WinActivate %spotify%
WinWaitActive %spotify%

;Right click near the song title in the "Now Playing" box.
WinGetPos,  ,  ,  , spotifyHeight, %spotify%
MouseClick, Right, 100, spotifyHeight - 70, 1, 0

;Get the contents of the context menu.
WinWait, ahk_class #32768
SendMessage, 0x1E1      ; MN_GETHMENU
allContextMenuInfo := ErrorLevel

;The "Star" command is the 5th menu item.
;If the song is Unstarred the text is Star, and vice versa. But sometimes some wierd characters are included.
;The only reliable way I found is to check if the first letter is S.
menuText_StarUnstar := GetContextMenuItemText(allContextMenuInfo, 5)
StringGetPos, positionOfS, menuText_StarUnstar, S

;If S is the first letter, star the song.
notStarred := (%positionOfS% = 0)
If notStarred {
    ;Arrow down to the Star menu item and press enter.
    MouseClick, Left, 20, -120, 1, 0,, R
} Else {
    ;Just close the context menu.
    Send {Escape}
}

;Restore original window and mouse position.
IfEqual MMX, -1, WinMinimize, %spotify%
WinActivate ahk_id %winID%
MouseMove %x%, %y%
}

Return

;Context menu helper function.
GetContextMenuItemText(hMenu, nPos)
{
length := DllCall("GetMenuString"
        , "UInt", hMenu
        , "UInt", nPos
        , "UInt", 0 ; NULL
        , "Int", 0  ; Get length
        , "UInt", 0x0400)   ; MF_BYPOSITION
    VarSetCapacity(lpString, length + 1)
    length := DllCall("GetMenuString"
        , "UInt", hMenu
        , "UInt", nPos
        , "Str", lpString
        , "Int", length + 1
        , "UInt", 0x0400)
return lpString
}
Источник
Другие вопросы по тегам