Remote Desktopping - 1 компьютерный контроль 30

Есть ли решение для удаленного рабочего стола, которое позволит одному компьютеру управлять 30? В компьютерной лаборатории у меня 30 студенческих компьютеров, на которых отображается одна и та же веб-страница. Я хочу, чтобы учитель мог нажать кнопку входа в систему и один раз ввести свои учетные данные вместо того, чтобы идти к каждому компьютеру и вводить его 30 раз.

Любое предложение будет полезно.

Источник

1 ответ

Я покажу вам, как я это сделаю: (у меня есть небольшой скрипт autologin для моего роутера, который я использовал здесь)

Установите AutoHotkey на все компьютеры.

На компьютере учителя создайте файл на рабочем столе с именем autologin.ahk:

mysite=http://192.168.178.1/logincheck.lua  ; the login site
myexpected=/home/home.lua                   ; part of the url after login
myuser=username                             ; username
mypass=password                             ; password

oIE:=ComObjCreate("InternetExplorer.Application")
oIE.Visible:=True
oIE.top:=oIE.left:=0, oIE.width:=A_ScreenWidth, oIE.height:=A_ScreenHeight
oIE.Navigate(mysite)
While oIE.readyState!=4 || oIE.document.readyState!="complete" || oIE.busy
   Sleep 50
SoundBeep

oForm:=oIE.document.getElementById("uiMainForm")    ; change this
oForm.elements.item("username").value:=myuser       ; change this
oForm.elements.item("uiPass").value:=mypass         ; change this
oForm.elements.item("uiSubmitLogin").Click()        ; change this
While oIE.readyState!=4 || oIE.document.readyState!="complete" || oIE.busy
   Sleep 50
SoundBeep

url:=oIE.LocationUrl
StringGetPos, pos, url, %myexpected%
if pos=-1
Loop
{
  Getkeystate, state, SPACE, P
  if state=D
    Break
  SoundBeep, 750, 500
  Sleep 50
}

Вам необходимо настроить переменную формы для вашего сайта. Если вход в систему не удастся, он будет подавать звуковые сигналы и продолжать звучать, пока вы не нажмете пробел. Вы можете проверить этот скрипт на компьютере учителя.

Теперь создайте checker.ahk:

script=\\teachers_computer\shared_folder\autologin.ahk
loop
{
  IfExist, %script%
  {
    run %script%
    sleep, 60000  ; 60 seconds
  }
  sleep 10000 ; 10 seconds
}

Запустите это при входе в систему компьютеров учеников. Он будет проверять общую папку на компьютере учителя каждые 10 секунд, если есть autologin.ahk, Если он есть, он будет выполнен и подождет 5 минут. (достаточно времени, чтобы учитель снова удалил файл.)

Учитель может переместить autologin.ahk со своего рабочего стола в общую папку и подождите, пока все компьютеры войдут в систему (это должно быть в течение 20 секунд). Затем он может переместить файл обратно на рабочий стол, чтобы он больше не был доступен студентам. Когда несколько компьютеров продолжают подавать звуковые сигналы, ему нужно перейти к ним и понять, почему логин не работает.

Не нужно говорить, что оригинал autohotkey.ahk должен быть защищен (я полагаю, что компьютер учителя защищен), и файл кратко раскрывается, когда он помещается в общую папку (но впоследствии непосредственно удаляется учителем). Поскольку это делается до того, как студенты прибывают за свои компьютеры, это не должно быть проблемой.

Источник
Другие вопросы по тегам