Как я могу навсегда отобразить команду vim:W на:w?

Иногда в VIM я держу смену, когда я сохраняю, и заканчиваю делать :W, Как мне настроить мой vimrc на распознавание :W как :w?

Источник

2 ответа

Решение

У меня тоже есть "ленивый" палец переключения, поэтому у меня есть несколько псевдонимов команд:

" "Aliases" for commonly used commands+lazy shift finger:
command! -bar -nargs=* -complete=file -range=% -bang W         <line1>,<line2>write<bang> <args>
command! -bar -nargs=* -complete=file -range=% -bang Write     <line1>,<line2>write<bang> <args>
command! -bar -nargs=* -complete=file -range=% -bang Wq        <line1>,<line2>wq<bang> <args>
command! -bar                                  -bang Wqall     wqa<bang>
command! -bar -nargs=* -complete=file -range=% -bang We        <line1>,<line2>w<bang> | e <args>
command! -bar -nargs=* -complete=file -count   -bang Wnext     <count>wnext<bang> <args>
command! -bar -nargs=* -complete=file -count   -bang Wprevious <count>wprevious<bang> <args>
command! -bar -nargs=* -complete=file          -bang E         edit<bang> <args>
command! -bar -nargs=* -complete=file          -bang Edit      edit<bang> <args>
command! -bar                                  -bang Q         quit<bang>
command! -bar                                  -bang Quit      quit<bang>
command! -bar                                  -bang Qall      qall<bang>
command! -bar -nargs=? -complete=option              Set       set <args>
command! -bar -nargs=? -complete=help                Help      help <args>
command! -bar -nargs=* -complete=file          -bang Make      make<bang> <args>
command! -bar -nargs=* -complete=buffer        -bang Bdel      bdel<bang> <args>
command! -bar -nargs=* -complete=buffer        -bang Bwipe     bwipe<bang> <args>
command! -bar -nargs=* -complete=file          -bang Mksession mksession<bang> <args>
command! -bar -nargs=* -complete=dir           -bang Cd        cd<bang> <args>
command! -bar                                        Messages  messages
command! -bar -nargs=+ -complete=file          -bang Source    source<bang> <args>

Причина у меня есть ряд дублированных команд, таких как W а также Write потому что у меня достаточно пользовательских команд, чтобы Vim мог жаловаться на неоднозначное использование пользовательских команд, если я этого не делаю. (Увидеть: :help user-cmd-ambiguous)

Источник

Вы не хотите отображать ключ, но создаете команду, которая ведет себя так же, как w(rite). Просто запишите это в $HOME/.vimrc:

command W write
Источник
Другие вопросы по тегам