Как вы работаете как другой пользователь из меню Пуск в Windows 10?

1. Откройте редактор реестра, нажав комбинацию клавиш Windows + R, введите regedit и нажмите Enter. Если запрос от UAC, нажмите Да, чтобы продолжить.
2. Идти к HKEY_CURRENT_USER\Software\Policies\Microsoft\Windows\Explorer - Если вы не нашли этот ключ, щелкните правой кнопкой мыши и добавьте ключ проводника в Windows и добавьте значение DWORD. ShowRunasDifferentuserinStart
3. На правой панели щелкните правой кнопкой мыши ShowRunasDifferentuserinStart ключ и затем нажмите Изменить.
4. Войти 1 как значение в поле данных значения
5. Нажмите Ok, чтобы сохранить настройки.
6. Закройте редактор реестра. Перезагрузите систему.

После перезагрузки у вас должна появиться опция "Запуск от имени другого пользователя", иногда в раскрывающемся списке "Дополнительно".

Я сделал это на нескольких компьютерах, подключенных к домену и не подключенных к домену, работает как шарм.

Источник: windows10update.com

Вы просто щелкните правой кнопкой мыши по ярлыку.

Вы также можете создать ярлык и использовать "runas" так же, как и любую версию Windows, как объяснил в этом ответе Chris Dwyer

1. Щелкните правой кнопкой мыши> Создать> Ярлык
2. В поле "Цель" введите "runas / user: ComputerName \ administrator program.exe"

.....

Чтобы создать ярлык с помощью команды runas

.....

Вы также можете использовать StartIsBack++, чтобы снова получить функциональность.

Если такая программа, как StartIsBack++, не может быть использована, вы можете включить ее с помощью меню "Пуск" и панели задач. Show "Run as different user" command on Start групповая политика на Включено

Связанные - Как добавить или удалить "Запуск от имени другого пользователя" на "Пуск" панели приложений в Windows 8 и 8.1

Существует другое (возможно, новое) решение для включения этой функциональности, которое гораздо проще, чем другие. Просто перейдите в " Настройки" > " Обновление и безопасность" > " Для разработчиков", и в проводнике Windows можно увидеть список вещей, которые можно применить.

Этот список вещей, которые вы можете применить, может быть немного сложным для понимания с первого взгляда, но я считаю, что он работает так: если он неактивен, то это означает, что эта конкретная вещь уже такая (включена) и нажатие на кнопку Применить активирует те, которые не выделены серым цветом и выбраны в настоящее время.

Следуя тому описанию, которое я только что составил, если кто-то хочет включить только политику изменения, чтобы в меню "Пуск" отображалось "Запускать от имени другого пользователя", он должен удалить проверки со всех остальных и нажать " Применить".

И, наконец, вот скриншот конкретной настройки, о которой я говорю:

Пока сервис вторичного входа в систему (seclogon), следующие блоки кода позволяют использовать комбинацию файлов Batch и VBScript для автоматизации задачи. пакетный файл использует относительные ссылки на пути, чтобы файлы могли быть помещены в любой путь, который позволяет, по крайней мере, разрешить чтение для текущей и выбранной учетных записей пользователей. Оба файла должны находиться в одном и том же пути. Использование ShellExecute с глаголом runasuser заставляет Windows вызывать запрос, позволяющий пользователю выбрать любой метод входа, разрешенный хост-компьютером.

Этот процесс можно добавить к процессам запуска пользователей, чтобы он происходил после входа в компьютерную систему.

Пакетный файл: {RunAsUser}{CMD}.cmd

@Echo Off

If "%~1" NEQ "/CALLBACK" Goto :label_Process_Run_As_User

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM Start the process once running as designated user
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

cd C:\
start "" %~dp0cmd.lnk

Goto :EOF

:label_Process_Run_As_User

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM Section below verifies if Secondary Login is available
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

REM Query [Secondary Logon]
sc query seclogon 1> nul 2> nul || (
    Goto :label_Missing_Secondary_Login
)

REM Check to see if [Secondary Logon] service is not disabled
sc qc seclogon | Find /i "START_TYPE" | Find /i "DISABLED" 1> nul 2> nul && (
    Set flg.SecLog.Enabled=F
) || (
    Set flg.SecLog.Enabled=T
)

REM Check to see if [Secondary Logon] service is Running
sc queryex seclogon | Find /i "STATE" | Find /i "RUNNING" 1> nul 2> nul && (
    Set flg.SecLog.Running=T
) || (
    Set flg.SecLog.Running=F
)

REM Determine if action should work
If /i "%flg.SecLog.Enabled%:%flg.SecLog.Running%" EQU "F:F" Goto :label_Secondary_Login_Unavailable

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM Section below starts the RunAsUser process
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

REM System configuration was validateed and RunAsUser will commence

Set "str.SELF=%~0"

WSCRIPT /E:VBSCRIPT "%~dp0RunAsUser.txt"

Goto :EOF

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM Section below provides written notices to user for error conditions
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:label_Secondary_Login_Unavailable
Echo.
Echo Unable to utilize the Secondary Logon system service because it is disabled.
Echo.
pause
Goto :EOF

:label_Missing_Secondary_Login
Echo.
Echo Unable to find the Secondary Logon system service
Echo.
pause
Goto :EOF

VBScript файл: RunAsUser.txt

'-------------------------------------------
'
' Launch Process RunAsUser
CreateObject("Shell.Application").ShellExecute CreateObject("WScript.Shell").Environment("PROCESS")("str.SELF"), "/CALLBACK", "", "runasuser", 1
'
' Display a message box to pause script
msgbox "Enter username or select Certificate for account" & vbCrLf & "On the windows dialog that will popup." & vbCrLf & vbCrLf & "Click OK once process opens", vbokonly
'
' Quit the script
On Error Resume Next
Window.Close ' HTA Must be Closed Through the Window Object
Err.Clear
Wscript.Quit ' VBS Must be Closed Through the Wscript Object
Err.Clear
On Error Goto 0
'
' ----------------------------------------------------------------------