Найдите часть строки, которая отличает строку в одной ячейке от строки в другой ячейке

У меня есть два столбца со строками, и я хочу знать, какие части строки из одного столбца имеют с другим столбцом. Я проверил это решение Сравните 2 текстовых ячейки и показать разницу в третьей ячейке | Супер пользователь, но это не работает для моей проблемы.

На скриншоте ниже я хочу, чтобы в столбце результатов была строка Elementary так как это то, что отличает B2 от A2, Я пытался с помощью =SUBSTITUTE(A2,B2,"") основанный на решении в ссылке выше, но формула делает противоположное, отображая общие строки в обоих столбцах:

Как сделать так, чтобы отображалась разница строк (Elementary) вместо?

Источник

1 ответ

Решение

Как я могу сделать так, чтобы вместо этого отображалась разница строк (элементарная)?

Вот пользовательская функция под названием WORDDIF это может делать то, что вы хотите.

Чтобы установить пользовательскую функцию...

  • Alt + F11, чтобы открыть редактор VBA
  • В меню VBA выберите "Вставка"> "Модуль".
  • Вставьте приведенный ниже код в окно редактирования VBA.

Вернувшись в Excel, поместите эту формулу в C1

=WORDDIF(A1,B1)

Код:

Function WORDDIF(rngA As Range, rngB As Range) As String

    Dim WordsA As Variant, WordsB As Variant
    Dim ndxA As Long, ndxB As Long, strTemp As String

    WordsA = Split(rngA.Text, " ")
    WordsB = Split(rngB.Text, " ")

    For ndxB = LBound(WordsB) To UBound(WordsB)
        For ndxA = LBound(WordsA) To UBound(WordsA)
            If StrComp(WordsA(ndxA), WordsB(ndxB), vbTextCompare) = 0 Then
                WordsA(ndxA) = vbNullString
                Exit For
            End If
        Next ndxA
    Next ndxB

    For ndxA = LBound(WordsA) To UBound(WordsA)
        If WordsA(ndxA) <> vbNullString Then strTemp = strTemp & WordsA(ndxA) & " "
    Next ndxA

    WORDDIF = Trim(strTemp)

End Function

Источник https://www.mrexcel.com/forum/excel-questions/486708-compare-two-strings-find-difference.html

Источник
Другие вопросы по тегам